|
| Boot file for Wordz
|
Set      Wordz$Dir      <Obey$Dir>
Set      Wordz$ImageDir <Wordz$Dir>
SetMacro Wordz$Path     <Wordz$UserPath><Wordz$Dir>.User.,<Wordz$Dir>.Resource.<Wordz$EndPath>
|
IconSprites <Wordz$ImageDir>.!Sprites
|
Set File$Type_BDF Firewrkz
|
Set File$Type_BE0 Recordz
|
Set File$Type_BE1 Resultz
|
Set File$Type_C1C Wordz
SetMacro Alias$@RunType_C1C   Run <Wordz$Dir>.!Run %%*0
SetMacro Alias$@PrintType_C1C Run <Wordz$Dir>.!Run -Print %%*0
|
Set File$Type_C1D FwrkzTem
SetMacro Alias$@RunType_C1D   Run <Wordz$Dir>.!Run -Template %%*0
SetMacro Alias$@PrintType_C1D Run <Wordz$Dir>.!Run -oPrint %%*0
|
Set File$Type_C1E FwrkzCmd
SetMacro Alias$@RunType_C1E   Run <Wordz$Dir>.!Run -Command %%*0
|
If "<File$Type_C32>"="" then Set File$Type_C32 RTF
If "<File$Type_DB0>"="" then Set File$Type_DB0 LotusWK1
If "<File$Type_DFE>"="" then Set File$Type_DFE CSV
|
SetEval Wordz$HasDOSFS 1
RMEnsure DOSFS 0.43 SetEval Wordz$HasDOSFS 0
If Wordz$HasDOSFS=1 then DOSMap TXT &FFF
If Wordz$HasDOSFS=1 then DOSMap RTF &C32
| If Wordz$HasDOSFS=1 then DOSMap WK1 &DB0 - doesn't accept numbers!
If Wordz$HasDOSFS=1 then DOSMap CSV &DFE
Unset Wordz$HasDOSFS
