SET Variations$Dir <Obey$Dir>

If "<Boot$OSVersion>" >= "500" Then IconSprites <Variations$Dir>.5Sprites Else If "<Boot$OSVersion>" >= "400" Then IconSprites <Variations$Dir>.4Sprites Else IconSprites <Variations$Dir>.!Sprites

RMENSURE OSVersion 1.06 IconSprites PCA:Support.clares_rd.nc_shared

RMENSURE CompoSupport 0.79 RMLOAD PCA:Support.clares_rd.SupportMod

If "<PCA$Path>"="" Then Error Please locate PCA resources.

rmensure PCASupport 0.33 run PCA:KickPCA
rmensure PCASupport 0.33 Error Version 0.33 or later of the PCA support module is required.

| following are old RISC OS versions that don't have these modules in ROM

RMENSURE CompressJPEG 0.0 RMLOAD System:Modules.JCompMod
rmensure CompressJPEG 0.0 error CompressJPEG 'jcompmod' module required.
RMEnsure DrawFile 0.00 RMLOAD System:Modules.DrawFile
RMEnsure DrawFile 0.00 ERROR Variations requires the Drawfile rendering module. Please install it in System or reinitialise it if in ROM.

RMEnsure SpriteExtend 0.99 RMLoad System:Modules.JPEGRender
RMEnsure SpriteExtend 0.99 RMLoad System:Modules.JPEGMsgs
RMEnsure SpriteExtend 0.99 RMENSURE JpegRender 0.00 Error Variations requires either SpriteExtend or JPEGRender.

*PCA_Register Variations.016.RobDavison.2002 ff9 110011 dpcavar,!variations <variations$Dir>.!Run -autobootpca

| Uncomment following if you want Variations to claim double clicks on jpegs and sprites

| Set Alias$@RunType_C85 RUN <Variations$Dir>.!Run %%*0
| Set Alias$@RunType_FF9 RUN <Variations$Dir>.!Run %%*0

Set File$Type_1c0 VariColl
Set Alias$@RunType_1c0 RUN <Variations$Dir>.!Run %%*0


| CompressJPEG finding...

WimpSlot 16K 16K
RMENSURE CompressJPEG 0 Run <Variations$Dir>.findjcomp


| Variations memory management
| Options are: "Auto" (this is the default)
|              "Wimpslot" (always use wimpslot - not recommended for RO 3&4)
|              "Dynamic" (always use dynamic areas - not a good idea on RO 5)

Set Variations$MemoryManager Auto

| Following is used for Dynamic areas only
| Being the address space of:
| "small workspaces" "large workspaces" and "image" respectively, in MB

Set Variations$AddressSpaces 8 32 128


WimpSlot 1488k 1488k
Run <Variations$Dir>.!RunImage %*0
