// loop1
// example script-file for writeflash

#define CIRCLE_ID       1
#define CIRCLE_DEPTH    1


FileVersion 1

FrameArea {
  width 4000
  height 4000
}

FrameRate 25.0

BackgroundColour 800000


DefineShape {
  id CIRCLE_ID
  fillstyle { solid ffffffff }
  selectfillstyle0 1
  // not really a circle, but who cares...
  moveby { 0 1000 }
  curveby { 0 1000 1000 0 }
  curveby { 1000 0 0 -1000 }
  curveby { 0 -1000 -1000 0 }
  curveby { -1000 0 0 1000 }
}

// create 30 frames - move the circle a bit to the left each time
:for loopi = 1 to 30
// don't remove the circle in the first frame - it hasn't been placed yet!
:if loopi > 1
RemoveObject { depth CIRCLE_DEPTH }
:endif

// place the circle
PlaceObject {
  depth CIRCLE_DEPTH
  id CIRCLE_ID
  // a matrix with 3 entries specifies scaling/positionx/positiony
  matrix { 65536 loopi*250-2000 500 }
}

// when at last frame, loop back to the start
:if loopi == 30
DoAction {
  gotoframe 0
  play
}
:endif

:print loopi
// end of frame - display it
ShowFrame { }
:next
