;------------------------------------------------------------------------------
;       FYEO
;       Frank Lyonnet 1993
;       Fonctions de conversion de couleur
;       Author : Frederic Elisei
;------------------------------------------------------------------------------

                GET     h.ASMRegs
                GET     h.SWInames

                AREA |C$$code|, CODE, READONLY

;------------------------------------------------------------------------------
;       rgb_to_gcol_convert_none
;------------------------------------------------------------------------------
;       parametre no 1 : pointeur vers le rouge
;       parametre no 2 : pointeur vers le vert
;       parametre no 3 : pointeur vers le bleu
;       parametre no 4 : pointeur vers le resultat
;       parametre no 5 : longueur d'une ligne
;       parametre no 6 : pointeur vers la table de dithering
;------------------------------------------------------------------------------
AROND   EQU     0
PAS     EQU     1

ARD     RN      0
AGR     RN      1
ABL     RN      2
DST     RN      3
LON     RN      4
RD      RN      5
GR      RN      6
BL      RN      7
COL     RN      8
TBL     RN      9

                EXPORT  |rgb_to_gcol_convert_none|
|rgb_to_gcol_convert_none|
                STMFD   sp!,{r4-r9}

                LDR     LON,[sp,#((6)*4)]        ;Longueur ligne
                LDR     TBL,[sp,#((6)*4+4)]      ;Pointeur table

AFFF            LDRB    RD,[ARD],#PAS
                LDRB    GR,[AGR],#PAS
                LDRB    BL,[ABL],#PAS

                MOV     GR,GR,LSR#3
                MOV     RD,RD,LSR#3
                ADD     RD,GR,RD,LSL#5
                ADD     RD,TBL,RD,LSL#5
                LDRB    COL,[RD,BL,LSR#3]

                STRB    COL,[DST],#1

                SUBS    LON,LON,#1
                BNE     AFFF

                LDMFD   sp!, {r4-r9}
                MOV     pc,lr ; RICK 2004/01/29 changed 'MOVS' to 'MOV'

                END
