Set From <Obey$Dir>
Filer_Boot Root:DDE.!DDEBoot

SetEval x0 0
SetEval y0 256
SetEval xgap 188
SetEval ygap -116
SetMacro Alias$NewColumn SetEval y <y0>|MSetEval x <x0>|MSetEval x0 <x0>+<xgap>|M
SetMacro Alias$Tack Pin %%0 <x> <y>|MSetEval y <y>-<ygap>|M

NewColumn
Tack <From>.^.!Director
Tack <From>.Director
Tack <From>.MakeFile
Tack <From>.o
Tack AssLib:hdr
Tack AssLib:hdr.Macros
Tack <From>.!Help

NewColumn
Tack <From>.s
Tack <From>.s.BMG
Tack <From>.s.Edit
Tack <From>.s.Filter
Tack <From>.s.Icons
Tack <From>.s.Memoriser
Tack <From>.s.Memory
Tack <From>.s.Menus
Tack <From>.s.Messages
Tack <From>.s.ModuleHead
Tack <From>.s.ModuleTail
Tack <From>.s.Sort
Tack <From>.s.Task

NewColumn
|Tack <From>.s
SetEval y <y>-<ygap>
Tack <From>.s.URL
Tack <From>.s.Windows

NewColumn
Tack <From>.h
Tack <From>.h.BMG
Tack <From>.h.Constants
Tack <From>.h.Edit
Tack <From>.h.Filter
Tack <From>.h.Icons
Tack <From>.h.ListMacros
Tack <From>.h.Memoriser
Tack <From>.h.Memory
Tack <From>.h.Menus
Tack <From>.h.Messages
Tack <From>.h.ModuleHead

NewColumn
|Tack <From>.h
Tack <From>.h.ModuleTail
Tack <From>.h.Sort
SetEval y <y>-<ygap>
Tack <From>.h.Task
Tack <From>.h.URL
Tack <From>.h.Version
Tack <From>.h.Windows
Tack <From>.h.WorkSpace

NewColumn
|Tack OS:hdr
|Tack OS:hdr.Wimp
|Tack OS:hdr.OS
|Tack Apps:Loads.!Trash.TrashSrc
|Tack ADFS::5.$.OldNews.In.Hensa.!KeyMouse.KeyMSource

NewColumn
Tack <From>.Menus
Tack <From>.Menus.User.NCW
Tack <From>.Menus.User.Default
Tack <From>.Menus.User.dL
Tack <From>.Menus.AutoRun

Unset x
Unset x0
Unset y
Unset y0
Unset Alias$NewColumn
Unset Alias$Tack
Filer_OpenDir <From>
Unset From

|Filer_Run Root:DDE.!DDEBoot
|Filer_Run Root:DDE.!DDT
|Filer_Run Root:DDE.!AMU
