|>!Run
|
| !Run file for Creator
|

Obey <Obey$Dir>.!Boot

RMEnsure UtilityModule 3.10 Error I need RISC OS 3.10 or later
RMEnsure UtilityModule 3.70 RMEnsure CallASWI 0.01 RMLoad System:Modules.CallASWI
RMEnsure UtilityModule 3.70 RmEnsure CallASWI 0.01 Error I need CallASWI 0.01 or later

If "<Wimp$ScrapDir>" = "" then Error Wimp$ScrapDir not defined

Set Creator$ModulesDir <Creator$Dir>.Modules
Set Creator$ChoicesDir <Creator$Dir>.Choices
If "<Choices$Write>" <> "" then Set Creator$ChoicesDir <Choices$Write>.Creator

RMEnsure FPEmulator 4.00 RMLoad System:Modules.FPEmulator
RMEnsure FPEmulator 4.00 Error I need FPEmulator 4.00 or later

RMEnsure ZeriRegister 0.00 RMLoad <Creator$ModulesDir>.ZRegister
RMEnsure ZeriWimpUtils 1.10 RMLoad <Creator$ModulesDir>.ZWimpUtils
RMEnsure ZeriWimpUtils 1.10 Error I need ZeriWimpUtils 1.10 or later
RMEnsure ZeriBuffer 1.10 RMLoad <Creator$ModulesDir>.ZBuffer
RMEnsure ZeriBuffer 1.10 Error I need ZeriBuffer 1.10 or later
RMEnsure ZeriArea 1.20 RMLoad <Creator$ModulesDir>.ZArea
RMEnsure ZeriArea 1.20 Error I need ZeriArea 1.20 or later

Set LoadModule No
RMEnsure ZeriConvert 1.20 Set LoadModule Yes
If "<LoadModule>" = "Yes" then RMLoad <Creator$ModulesDir>.ZConvert
If "<LoadModule>" = "Yes" then Set ZeriConvert$BinDir <Creator$Dir>.Bin
If "<LoadModule>" = "Yes" then Set ZeriConvert$ScrapDir <Wimp$ScrapDir>
Unset LoadModule
RMEnsure ZeriConvert 1.20 Error I need ZeriConvert 1.20 or later

| If dynamic areas are not available, ensure the wimp slot is large
| enough or Creator will crash when running out of memory. Change
| the second line for RISC OS versions before 3.50, else the first.
WimpSlot -min 544K -max 544K
RMEnsure UtilityModule 3.50 WimpSlot -min 576K -max 576K

RegisterModule ZeriWimpUtils
RegisterModule ZeriConvert
RegisterModule ZeriBuffer
RegisterModule ZeriArea

Run <Creator$Dir>.!RunImage %*0

UnregisterModule ZeriWimpUtils
UnregisterModule ZeriConvert
UnregisterModule ZeriBuffer
UnregisterModule ZeriArea