; HST DS+ modem driver (V42bis)                        Version 1.00 31-Oct-1991
; (c) 1990/1991 Hugo Fiennes

modem_initialise ()
  {
  integer oldtx=port_txspeed(),oldrx=port_rxspeed()

  port_rxclear()
  port_txspeed(19200)
  port_rxspeed(19200)
              
  type "AT"+cr
  pause(20)
  type "AT&C1&D2S27=0S19=0S9=1S10=1S28=8"+cr
  pause(30)
  port_rxclear()

  type "ATQ0V1E0X4S0=0&B1&M4&K2&N0&R2&I0&H1&A3"+cr
  if (waitfor("OK",150))
    {
    port_txspeed(oldtx)
    port_rxspeed(oldrx)
    return(0)
    }

  port_txspeed(oldtx)
  port_rxspeed(oldrx)
  return(1)
  }

modem_shutdown ()
  {
  return(1)
  }

modem_connect ()
  {
  integer sv=0

  if (port_txspeed()==75)
    {
    port_txspeed(1200)
    sv=8
    }

  port_dtr(1)
  port_rts(1)
  type "ATS34="+$str(sv)+"D"+cr

  return(_processmessage(""))
  }

modem_disconnect ()
  {
  type cr 
  pause(10)
  port_rts(0)
  port_dtr(0)
  pause(50)
  port_dtr(1)
  port_rts(1)
  pause(10)
  type cr
  }

modem_dial (string number[40],integer how)
  {
  string dialtype[1]
  integer sv=0

  port_dtr(1)
  port_rts(1)
  port_rxclear()

  if (how==0)
    {
    dialtype="P"
    }
  else
    {
    dialtype="T"
    }

  if (port_txspeed()==75)
    {
    port_txspeed(1200)
    sv=8
    }

  port_rxclear()
  type "ATS34="+$str(sv)+"D"+dialtype+number+cr

  return(_processmessage(""))
  }

modem_answer ()
  {
  string response[50]

  type "ATS0=1"+cr

  repeat
    {
    response=$modeminput(50,modem_replywait)
    }
  until(strcmp($left(response,7),"CONNECT")==0)

  return(_processmessage(response))
  }

modem_errorcontrol (string option[10])
  {
  set(linklevel,none)

  if (comparei(option,"off"))
    {
    type("AT&M0"+cr)
    }

  if (comparei($left(option,3),"mnp"))
    {
    integer level=val($mid(option,4,1))
 
    if (level>=5)
      {
      type("AT&M4&K2"+cr)
      }
    else
      {
      type("AT&M4&K0"+cr)
      }
    }

  if (comparei(option,"vasscom"))
    {
    type("AT&M0"+cr)
    set(linklevel,vasscom)
    }

  waitfor("OK"+$chr(13)+$chr(10),100)
  pause(50)
  }

modem_standard (string option[10])
  {
  integer number=val(option)

  if (comparei(option,"v21") || number==300)
    {
    type "AT&N1"+cr
    waitfor("OK"+$chr(13)+$chr(10),100)
    return
    }
  if (comparei(option,"v22") || number==1200)
    {
    type "AT&N2"+cr
    waitfor("OK"+$chr(13)+$chr(10),100)
    return
    }
  if (comparei(option,"v22bis") || number==2400)
    {
    type "AT&N3"+cr
    waitfor("OK"+$chr(13)+$chr(10),100)
    return
    }
  if (comparei(option,"v27") || number=4800)
    {
    type "AT&N4"+cr
    waitfor("OK"+$chr(13)+$chr(10),100)
    return
    }
  if (number=7200)
    {
    type "AT&N5"+cr
    waitfor("OK"+$chr(13)+$chr(10),100)
    return
    }
  if (comparei(option,"v32") || number=9600)
    {
    type "AT&N6"+cr
    waitfor("OK"+$chr(13)+$chr(10),100)
    return
    }
  if (comparei(option,"hst") || comparei(option,"fastest") || number=19200)
    {
    type "AT&N0"+cr
    waitfor("OK"+$chr(13)+$chr(10),100)
    return
    }
  prints "Modem standard "+option+" is not supported."+newline
  }

_processmessage (string already[50])
  {
  string retcode[50]

  if (len(already)==0)
    {
    ; Wait for message
    retcode=$modeminput(50,modem_replywait)
    if (len(retcode)==0)
      {
      retcode=$modeminput(50,modem_replywait)
      }
    }
  else
    {
    retcode=already
    }

  ; Check for NO DIAL TONE/BLACKLISTED/BUSY
  switch(retcode)
    {
    case$("BUSY")
      {
      return(2)
      }
    case$("NO DIAL TONE")
      {
      return(3)
      }
    case$("BLACKLISTED")
      {
      return(4)
      }
    }

  if (compare($left(retcode,7),"CONNECT"))
    {
    prints retcode+newline
    return(0)
    }

  modem_disconnect()
  return(1)
  }
