; Alternate Hayes modem driver 2                    Version 1.03 25-Feb-1991
; (c) 1990/1991 Hugo Fiennes
; Note: This driver may well not work properly with the host mode

modem_initialise ()
  {
  integer oldtx=port_txspeed(),oldrx=port_rxspeed()

  port_rxclear()
  port_txspeed(300)
  port_rxspeed(300)

  type "AT"+cr
  pause(70)
  port_rxclear()

  type "ATQ0V1E0X1S0=0"+cr
  if (waitfor("OK",150))
    {
    port_txspeed(oldtx)
    port_rxspeed(oldrx)
    return(0)
    }

  port_txspeed(oldtx)
  port_rxspeed(oldrx)
  return(1)
  }

modem_shutdown ()
  {
  return(1)
  }

modem_connect ()
  {
  port_dtr(1)
  port_rts(1)
  type "ATO"+cr

  return(_processmessage(""))
  }

modem_disconnect ()
  {
  port_rts(0)
  port_dtr(0)
  pause 50
  port_dtr(1)
  port_rts(1)
  type cr
  }

modem_dial (string number[40],integer how)
  {
  string dialtype[1]

  port_dtr(1)
  port_rts(1)
  port_rxclear()

  if (how==0)
    {
    dialtype="P"
    }
  else
    {
    dialtype="T"
    }

  type "ATD"+dialtype+number+cr

  return(_processmessage(""))
  }

modem_answer ()
  {
  string response[30]

  type "ATS0=1"+cr

  repeat
    {
    response=$modeminput(30,modem_replywait)
    }
  until(strcmp($left(response,7),"CONNECT")==0)

  return(_processmessage(response))
  }

modem_errorcontrol (string option[10])
  {
  set(linklevel,none)

  if (comparei(option,"vasscom"))
    {
    set(linklevel,vasscom)
    return
    }

  if (comparei($left(option,3),"mnp"))
    {
    set(linklevel,mnp)
    return
    }
  }

modem_standard (string option[10])
  {
  if (comparei(option,"v21"))
    {
    port_txspeed(300)
    port_rxspeed(300)
    return
    }
  if (comparei(option,"v22"))
    {
    port_txspeed(1200)
    port_rxspeed(1200)
    return
    }
  if (comparei(option,"v22bis"))
    {
    port_txspeed(2400)
    port_rxspeed(2400)
    return
    }
  if (comparei(option,"v27"))
    {
    port_txspeed(4800)
    port_rxspeed(4800)
    return
    }
  if (comparei(option,"v32"))
    {
    port_txspeed(9600)
    port_rxspeed(9600)
    return
    }
  if (comparei(option,"v32bis"))
    {
    port_txspeed(19200)
    port_rxspeed(19200)
    return
    }
  prints "Modem standard "+option+" is not supported."+newline
  }

_processmessage (string already[30])
  {
  integer t=clock()

  repeat
    {
    }
  until(((clock()-t)>modem_replywait) || (port_dcd()!=0))

  if (port_dcd()!=0)
    {
    return(0)
    }

  modem_disconnect()
  return(1)
  }
