        TTL     > FS10 : Language bits

        ^       &0400           ; Language workspace
lineb_length *  256
linebuffer #    lineb_length

 ASSERT @ <= &0800

; +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

Language ROUT

starloop
        GENAD   brkhandler
        STXY    brkv

        JSR     vstring
        =       "65*"
        NOP

        LDAIM   0
        GENAD   word0block
        JSR     osword
        BCS     #FT90

        GENAD   linebuffer
        JSR     oscli

        JMP     starloop


90      JSR     AckEscape

        BRK                     ; We are current, therefore ok
mEscape
        =       17
        =       "Escape", 0

; +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

word0block
        &       linebuffer
        =       lineb_length-1
        =       " "
        =       255

; +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

brkhandler ROUT

        LDXIM   &FF
        TXS
        CLI
        JSR     osnewl

        LDYIM   1
10      LDAIY   brkptr
        BEQ     #FT50
        JSR     oswrch
        INY
        BNE     #BT10           ; Safer than BRA

50      JSR     osnewl
        JMP     starloop

; +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

        LNK     FS15
